Отправка Email из Oracle PL/SQL (UTL

Пакет UTL_SMTP был представлен в Oracle 8i и может использоваться для отправки электронных писем из PL/SQL.

Простое письмо

Простое письмо может быть отправлено, используя следующую процедуру. В этом случае мы не включали информации о заголовке сообщения, таким образом, это не очень полезно, но это простейший пример.

CREATE OR REPLACE PROCEDURE send_mail (p_to IN VARCHAR2,

p_from IN VARCHAR2,

p_message IN VARCHAR2,

p_smtp_host IN VARCHAR2,

p_smtp_port IN NUMBER DEFAULT 25)

l_mail_conn UTL_SMTP.connection;

BEGIN

l_mail_conn := UTL_SMTP.open_connection(p_smtp_host, p_smtp_port);

UTL_SMTP.helo(l_mail_conn, p_smtp_host);

UTL_SMTP.mail(l_mail_conn, p_from);

UTL_SMTP.rcpt(l_mail_conn, p_to);

UTL_SMTP.data(l_mail_conn, p_message || UTL_TCP.crlf || UTL_TCP.crlf);

UTL_SMTP.quit(l_mail_conn);

END;

Код ниже показывает, как вызвать эту процедуру:

BEGIN

send_mail(p_to => 'me@mycompany.com',

p_from => 'admin@mycompany.com',

p_message => 'This is a test message.',

p_smtp_host => 'smtp.mycompany.com');

END;

Письмо из нескольких строк

Многострочные сообщения могут быть записаны, используя UTL_SMTP.DATA и команду UTL_SMTP.WRITE_DATA следующим образом. Это - лучший метод использования, поскольку полный размер сообщения больше не ограничен 32 K переменной VARCHAR2. В следующем примере информация заголовка была также включена в сообщение.

CREATE OR REPLACE PROCEDURE send_mail (p_to IN VARCHAR2,

p_from IN VARCHAR2,

p_subject IN VARCHAR2,

p_message IN VARCHAR2,

p_smtp_host IN VARCHAR2,

p_smtp_port IN NUMBER DEFAULT 25)

l_mail_conn UTL_SMTP.connection;

BEGIN

l_mail_conn := UTL_SMTP.open_connection(p_smtp_host, p_smtp_port);

UTL_SMTP.helo(l_mail_conn, p_smtp_host);

UTL_SMTP.mail(l_mail_conn, p_from);

UTL_SMTP.rcpt(l_mail_conn, p_to);

UTL_SMTP.open_data(l_mail_conn);

UTL_SMTP.write_data(l_mail_conn, 'Date: ' || TO_CHAR(SYSDATE, 'DD-MON-YYYY HH24:MI:SS') || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'To: ' || p_to || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'From: ' || p_from || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Subject: ' || p_subject || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Reply-To: ' || p_from || UTL_TCP.crlf || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, p_message || UTL_TCP.crlf || UTL_TCP.crlf);

UTL_SMTP.close_data(l_mail_conn);

UTL_SMTP.quit(l_mail_conn);

END;

Код ниже показывает, как вызвать эту процедуру:

BEGIN

send_mail(p_to => 'me@mycompany.com',

p_from => 'admin@mycompany.com',

p_subject => 'Test Message',

p_message => 'This is a test message.',

p_smtp_host => 'smtp.mycompany.com');

END;

Письмо в формате HTML

Следующая процедура основывается на предыдущей версии, позволяя включать простой текст и/или HTML в письмо электронной почты.

CREATE OR REPLACE PROCEDURE send_mail (p_to IN VARCHAR2,

p_from IN VARCHAR2,

p_subject IN VARCHAR2,

p_text_msg IN VARCHAR2 DEFAULT NULL,

p_html_msg IN VARCHAR2 DEFAULT NULL,

p_smtp_host IN VARCHAR2,

p_smtp_port IN NUMBER DEFAULT 25)

l_mail_conn UTL_SMTP.connection;

l_boundary VARCHAR2(50) := '----=*#abc1234321cba#*=';

BEGIN

l_mail_conn := UTL_SMTP.open_connection(p_smtp_host, p_smtp_port);

UTL_SMTP.helo(l_mail_conn, p_smtp_host);

UTL_SMTP.mail(l_mail_conn, p_from);

UTL_SMTP.rcpt(l_mail_conn, p_to);

UTL_SMTP.open_data(l_mail_conn);

UTL_SMTP.write_data(l_mail_conn, 'Date: ' || TO_CHAR(SYSDATE, 'DD-MON-YYYY HH24:MI:SS') || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'To: ' || p_to || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'From: ' || p_from || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Subject: ' || p_subject || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Reply-To: ' || p_from || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'MIME-Version: 1.0' || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Type: multipart/alternative; boundary="' || l_boundary || '"' || UTL_TCP.crlf || UTL_TCP.crlf);

IF p_text_msg IS NOT NULL THEN

UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Type: text/plain; charset="iso-8859-1"' || UTL_TCP.crlf || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, p_text_msg);

UTL_SMTP.write_data(l_mail_conn, UTL_TCP.crlf || UTL_TCP.crlf);

END IF;

IF p_html_msg IS NOT NULL THEN

UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Type: text/html; charset="iso-8859-1"' || UTL_TCP.crlf || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, p_html_msg);

UTL_SMTP.write_data(l_mail_conn, UTL_TCP.crlf || UTL_TCP.crlf);

END IF;

UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || '--' || UTL_TCP.crlf);

UTL_SMTP.close_data(l_mail_conn);

UTL_SMTP.quit(l_mail_conn);

END;

Код ниже показывает, как вызвать эту процедуру:

DECLARE

l_html VARCHAR2(32767);

BEGIN

l_html := '

Отправка Email из Oracle PL/SQL (UTL_SMTP)

This is a HTML version of the test message.

Site Logo

send_mail(p_to => 'me@mycompany.com',

p_from => 'admin@mycompany.com',

p_subject => 'Test Message',

p_text_msg => 'This is a test message.',

p_html_msg => l_html,

p_smtp_host => 'smtp.mycompany.com');

END;

Письмо с вложениями

Отправка электронного письма с вложением подобно предыдущему примеру, но вложение должно быть отделено и идентифицировано MIME типом и именем.

Вложение из BLOB

Вложение из BLOB требует, чтобы двоичные данные были закодированы и преобразованы в текст, и только после этого оно может быть отправлено через используя SMTP.

CREATE OR REPLACE PROCEDURE send_mail (p_to IN VARCHAR2,

p_from IN VARCHAR2,

p_subject IN VARCHAR2,

p_text_msg IN VARCHAR2 DEFAULT NULL,

p_attach_name IN VARCHAR2 DEFAULT NULL,

p_attach_mime IN VARCHAR2 DEFAULT NULL,

p_attach_blob IN BLOB DEFAULT NULL,

p_smtp_host IN VARCHAR2,

p_smtp_port IN NUMBER DEFAULT 25)

l_mail_conn UTL_SMTP.connection;

l_boundary VARCHAR2(50) := '----=*#abc1234321cba#*=';

l_step PLS_INTEGER := 24573;

BEGIN

l_mail_conn := UTL_SMTP.open_connection(p_smtp_host, p_smtp_port);

UTL_SMTP.helo(l_mail_conn, p_smtp_host);

UTL_SMTP.mail(l_mail_conn, p_from);

UTL_SMTP.rcpt(l_mail_conn, p_to);

UTL_SMTP.open_data(l_mail_conn);

UTL_SMTP.write_data(l_mail_conn, 'Date: ' || TO_CHAR(SYSDATE, 'DD-MON-YYYY HH24:MI:SS') || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'To: ' || p_to || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'From: ' || p_from || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Subject: ' || p_subject || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Reply-To: ' || p_from || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'MIME-Version: 1.0' || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Type: multipart/mixed; boundary="' || l_boundary || '"' || UTL_TCP.crlf || UTL_TCP.crlf);

IF p_text_msg IS NOT NULL THEN

UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Type: text/plain; charset="iso-8859-1"' || UTL_TCP.crlf || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, p_text_msg);

UTL_SMTP.write_data(l_mail_conn, UTL_TCP.crlf || UTL_TCP.crlf);

END IF;

IF p_attach_name IS NOT NULL THEN

UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Type: ' || p_attach_mime || '; name="' || p_attach_name || '"' || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Transfer-Encoding: base64' || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Disposition: attachment; filename="' || p_attach_name || '"' || UTL_TCP.crlf || UTL_TCP.crlf);

FOR i IN 0 .. TRUNC((DBMS_LOB.getlength(p_attach_blob) - 1 )/l_step) LOOP

UTL_SMTP.write_data(l_mail_conn, UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(DBMS_LOB.substr(p_attach_blob, l_step, i * l_step + 1))));

END LOOP;

UTL_SMTP.write_data(l_mail_conn, UTL_TCP.crlf || UTL_TCP.crlf);

END IF;

UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || '--' || UTL_TCP.crlf);

UTL_SMTP.close_data(l_mail_conn);

UTL_SMTP.quit(l_mail_conn);

END;

Код ниже показывает, как вызвать эту процедуру:

DECLARE

l_name images.name%TYPE := 'site_logo.gif';

l_blob images.image%TYPE;

BEGIN

SELECT image

INTO l_blob

FROM images

WHERE name = l_name;

send_mail(p_to => 'me@mycompany.com',

p_from => 'admin@mycompany.com',

p_subject => 'Test Message',

p_text_msg => 'This is a test message.',

p_attach_name => 'site_logo.gif',

p_attach_mime => 'image/gif',

p_attach_blob => l_blob,

p_smtp_host => 'smtp.mycompany.com');

END;

Вложение из CLOB

Вложение из CLOB подобно вложению из BLOB, но мы не должны волноваться о кодировании данных, потому что это уже простой текст.

CREATE OR REPLACE PROCEDURE send_mail (p_to IN VARCHAR2,

p_from IN VARCHAR2,

p_subject IN VARCHAR2,

p_text_msg IN VARCHAR2 DEFAULT NULL,

p_attach_name IN VARCHAR2 DEFAULT NULL,

p_attach_mime IN VARCHAR2 DEFAULT NULL,

p_attach_clob IN CLOB DEFAULT NULL,

p_smtp_host IN VARCHAR2,

p_smtp_port IN NUMBER DEFAULT 25)

l_mail_conn UTL_SMTP.connection;

l_boundary VARCHAR2(50) := '----=*#abc1234321cba#*=';

l_step PLS_INTEGER := 24573;

BEGIN

l_mail_conn := UTL_SMTP.open_connection(p_smtp_host, p_smtp_port);

UTL_SMTP.helo(l_mail_conn, p_smtp_host);

UTL_SMTP.mail(l_mail_conn, p_from);

UTL_SMTP.rcpt(l_mail_conn, p_to);

UTL_SMTP.open_data(l_mail_conn);

UTL_SMTP.write_data(l_mail_conn, 'Date: ' || TO_CHAR(SYSDATE, 'DD-MON-YYYY HH24:MI:SS') || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'To: ' || p_to || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'From: ' || p_from || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Subject: ' || p_subject || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Reply-To: ' || p_from || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'MIME-Version: 1.0' || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Type: multipart/mixed; boundary="' || l_boundary || '"' || UTL_TCP.crlf || UTL_TCP.crlf);

IF p_text_msg IS NOT NULL THEN

UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Type: text/plain; charset="iso-8859-1"' || UTL_TCP.crlf || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, p_text_msg);

UTL_SMTP.write_data(l_mail_conn, UTL_TCP.crlf || UTL_TCP.crlf);

END IF;

IF p_attach_name IS NOT NULL THEN

UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Type: ' || p_attach_mime || '; name="' || p_attach_name || '"' || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Disposition: attachment; filename="' || p_attach_name || '"' || UTL_TCP.crlf || UTL_TCP.crlf);

FOR i IN 0 .. TRUNC((DBMS_LOB.getlength(p_attach_clob) - 1 )/l_step) LOOP

UTL_SMTP.write_data(l_mail_conn, DBMS_LOB.substr(p_attach_clob, l_step, i * l_step + 1));

END LOOP;

UTL_SMTP.write_data(l_mail_conn, UTL_TCP.crlf || UTL_TCP.crlf);

END IF;

UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || '--' || UTL_TCP.crlf);

UTL_SMTP.close_data(l_mail_conn);

UTL_SMTP.quit(l_mail_conn);

END;

Код ниже показывает, как вызвать эту процедуру:

DECLARE

l_clob CLOB := 'This is a very small CLOB!';

BEGIN

send_mail(p_to => 'me@mycompany.com',

p_from => 'admin@mycompany.com',

p_subject => 'Test Message',

p_text_msg => 'This is a test message.',

p_attach_name => 'test.txt',

p_attach_mime => 'text/plain',

p_attach_clob => l_clob,

p_smtp_host => 'smtp.mycompany.com');

END;

Разное

Для электронных писем с многими получателями просто вызовите процедуру RCPT для каждого отдельного адреса электронной почты.

Пакет UTL_SMTP требует Jserver, который может быть установлен, выполнив следующие сценарии как SYS.

SQL> @$ORACLE_HOME/javavm/install/initjvm.sql

SQL> @$ORACLE_HOME/rdbms/admin/initplsj.sql

< Предыдущая		Следующая >

DeepEdit!